[client] build: add Windows platform composition

client/cmake/FindANGLE.cmake

@@ -0,0 +1,70 @@
+set(ANGLE_ROOT "" CACHE PATH "Root of a prebuilt ANGLE distribution")
+
+if(ANGLE_ROOT)
+  set(_ANGLE_HINTS       HINTS "${ANGLE_ROOT}")
+  set(_ANGLE_FIND_POLICY NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
+endif()
+
+find_path(ANGLE_EGL_INCLUDE_DIR
+  NAMES EGL/egl.h
+  ${_ANGLE_HINTS}
+  PATH_SUFFIXES include
+  ${_ANGLE_FIND_POLICY}
+)
+
+find_path(ANGLE_GLES_INCLUDE_DIR
+  NAMES GLES3/gl32.h
+  ${_ANGLE_HINTS}
+  PATH_SUFFIXES include
+  ${_ANGLE_FIND_POLICY}
+)
+
+find_library(ANGLE_EGL_LIBRARY
+  NAMES EGL libEGL
+  ${_ANGLE_HINTS}
+  PATH_SUFFIXES lib lib64
+  ${_ANGLE_FIND_POLICY}
+)
+
+find_library(ANGLE_GLESV2_LIBRARY
+  NAMES GLESv2 libGLESv2
+  ${_ANGLE_HINTS}
+  PATH_SUFFIXES lib lib64
+  ${_ANGLE_FIND_POLICY}
+)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(ANGLE
+  REQUIRED_VARS
+    ANGLE_EGL_INCLUDE_DIR
+    ANGLE_GLES_INCLUDE_DIR
+    ANGLE_EGL_LIBRARY
+    ANGLE_GLESV2_LIBRARY
+)
+
+mark_as_advanced(
+  ANGLE_EGL_INCLUDE_DIR
+  ANGLE_GLES_INCLUDE_DIR
+  ANGLE_EGL_LIBRARY
+  ANGLE_GLESV2_LIBRARY
+)
+
+if(ANGLE_FOUND AND NOT TARGET ANGLE::GLESv2)
+  add_library(ANGLE::GLESv2 UNKNOWN IMPORTED)
+  set_target_properties(ANGLE::GLESv2 PROPERTIES
+    IMPORTED_LOCATION             "${ANGLE_GLESV2_LIBRARY}"
+    INTERFACE_INCLUDE_DIRECTORIES "${ANGLE_GLES_INCLUDE_DIR}"
+  )
+endif()
+
+if(ANGLE_FOUND AND NOT TARGET ANGLE::EGL)
+  add_library(ANGLE::EGL UNKNOWN IMPORTED)
+  set_target_properties(ANGLE::EGL PROPERTIES
+    IMPORTED_LOCATION             "${ANGLE_EGL_LIBRARY}"
+    INTERFACE_INCLUDE_DIRECTORIES "${ANGLE_EGL_INCLUDE_DIR}"
+    INTERFACE_LINK_LIBRARIES      ANGLE::GLESv2
+  )
+endif()
+
+unset(_ANGLE_HINTS)
+unset(_ANGLE_FIND_POLICY)

client/cmake/FindSampleRate.cmake

@@ -0,0 +1,44 @@
+set(SampleRate_ROOT "" CACHE PATH
+  "Root of a prebuilt libsamplerate distribution")
+
+if(SampleRate_ROOT)
+  set(_SampleRate_HINTS       HINTS "${SampleRate_ROOT}")
+  set(_SampleRate_FIND_POLICY NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
+endif()
+
+find_path(SampleRate_INCLUDE_DIR
+  NAMES samplerate.h
+  ${_SampleRate_HINTS}
+  PATH_SUFFIXES include
+  ${_SampleRate_FIND_POLICY}
+)
+
+find_library(SampleRate_LIBRARY
+  NAMES samplerate libsamplerate
+  ${_SampleRate_HINTS}
+  PATH_SUFFIXES lib lib64
+  ${_SampleRate_FIND_POLICY}
+)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(SampleRate
+  REQUIRED_VARS
+    SampleRate_INCLUDE_DIR
+    SampleRate_LIBRARY
+)
+
+mark_as_advanced(
+  SampleRate_INCLUDE_DIR
+  SampleRate_LIBRARY
+)
+
+if(SampleRate_FOUND AND NOT TARGET SampleRate::samplerate)
+  add_library(SampleRate::samplerate UNKNOWN IMPORTED)
+  set_target_properties(SampleRate::samplerate PROPERTIES
+    IMPORTED_LOCATION             "${SampleRate_LIBRARY}"
+    INTERFACE_INCLUDE_DIRECTORIES "${SampleRate_INCLUDE_DIR}"
+  )
+endif()
+
+unset(_SampleRate_HINTS)
+unset(_SampleRate_FIND_POLICY)